add space-travel-{1,2,3,4,5,6,7}.s

scans/README.md

@@ -55,3 +55,10 @@ Details of the files:
 * as.s: pages 32-48 of 05-1-4.pdf
 * ed1.s: pages 7-20 of 08-rest.pdf
 * ed2.s: pages 21-29 of 08-rest.pdf
+* space-travel-1.s pages 1-5 of 12-92-119.pdf
+* space-travel-2.s pages 6-9 of 12-92-119.pdf
+* space-travel-3.s pages 10-13 of 12-92-119.pdf
+* space-travel-4.s pages 14-18 of 12-92-119.pdf
+* space-travel-5.s pages 19-20 of 12-92-119.pdf
+* space-travel-6.s pages 21-25 of 12-92-119.pdf
+* space-travel-7.s pages 26-28 of 12-92-119.pdf

scans/space-travel-1.s

@@ -0,0 +1,248 @@
+! space travel 1
+
+t = 0
+
+start:
+   law 13
+   sys sysloc
+   dac .pbson
+   lac pww
+   dac 1f
+   dac 2f
+   lac pw
+   dac 3f
+   -32
+   dac cplan
+4:
+   fld; 1:0
+   fmp; 2:0
+   -1
+   tad aexp
+   dac aexp
+   fng
+   fad; fpone
+   fst; 3:0
+   lac 1b
+   tad d3
+   dac 1b
+   dac 2b
+   lac 3b
+   tad 3d
+   dac 3b
+   isz cplan
+   jmp 4b
+   law dspl-1
+   dac clistp
+   dac lanflg
+   dzm crflg
+   dzm goflg
+   dzm .pbsint
+   dzm forflg
+   dzm bacflg
+   dzm dspflg
+   dzm locflg
+   dzm locpar
+   lac d1
+   dac par
+   jms dispname
+   fld; prsq+4
+   sqrt
+   fst; rpar
+   fst; y
+   fst; oy
+   fld; fpone
+   fst; sphi
+   fst; stheta
+   jms dspsca
+   fld; fpzero
+   fst; x
+   fst; ox
+   fst; cphi
+   fst; ctheta
+   law displist
+   sys capt
+   jmp loop
+
+loop:
+   law dspl-1
+   dac clistp
+   jms contrl
+   lac par
+   jms absxy
+   jms shipxy
+   lac goflg
+   spa
+   jmp loop3
+   fld; fpzero
+   fst; ax
+   fst; ay
+   fst; maxa
+   lac nplan
+   skp
+loop1:
+   lac cplan
+   tad dm1
+   spa
+   jmp loop2
+   dac cplan
+   tad fppar
+   dac fcplan
+   lac i fcplan
+   dac fcplan
+   jms updacc
+   jms displa
+   lac cplan
+   sza
+   jms updpln
+   lac cplan
+   and o7
+   sad o7
+   jms contrl
+   jmp loop1
+
+loop2:
+   lac lanflg
+   sma
+   jms updshp
+loop3:
+   fld; horizv
+   lac scale
+   cma
+   tad vscale
+   tad aexp
+   dac aexp
+   jms inscr
+      jmp loop4
+   tad o141577
+   dac i clistp
+   lac o164372
+   dac clistp i
+   cla
+   jms dsplanet
+loop4:
+   sys time "put delay here.....
+   dzm dispcl
+   lac crflg
+   sma
+   jmp 1f
+   lac o20714 "cl
+   dac dispcl
+   jmp 2f
+1:
+   lac lanflg
+   sma
+   jmp 2f
+   lac o114 "l
+   dac dispcl
+2:
+   lac dhalt
+   dac i clistp
+   jmp loop " check 2-display question
+
+contrl: 0
+   lac i .pbson
+   xor .pbsint
+   and .pbson i
+   sna
+   jmp noneon
+   lmq
+   spa ral
+   sys exit
+   sma
+   jmp 1f
+   dzm goflg
+   dzm crflg
+1:
+   lacq
+   als 6
+   sma ral
+   jmp 1f
+   spa
+   jmp noneon
+   isz scale
+   nop
+   jms dspsca "uprange
+   jmp noneon
+1:
+   sma
+   jmp noneon
+   -1
+   tad scale
+   dac scale
+   jms dspsca "downrange
+noneon:
+   dzm forflg
+   dzm bacflg
+   lac i .pbson
+   dac .pbsint
+   als 2
+   sma
+   jmp 1f
+   lac dhalt
+   dac forflg
+   lac goflg
+   sma
+   dzm lanflg
+1:
+   lac i .pbson
+   als 3
+   sma
+   jmp 1f
+   lac dhalt
+   dac bacflg
+   lac goflg
+   sma
+   dzm lanflg
+1:
+   lac i .pbson
+   als 4
+   sma
+   jmp 1f
+   ral
+   spa
+   jmp i contrl
+   dzm 9f+t
+   jmp 2f
+1:
+   ral
+   sma
+   jmp i contrl
+   lac dhalt
+   dac 9f+t
+2:
+   fld; cphi
+   fmp; sdphi
+   lac 9f+t
+   sma
+   fng
+   fst; ftmp1
+   fld; sphi
+   fmp; cdphi
+   fad; ftmp1
+   fst; ftmp2
+   fld; sphi
+   fmp; sdphi
+   lac 9f+t
+   spa
+   fng
+   fst; ftmp1
+   fld; cphi
+   fmp; cdphi
+   fad; ftmp1
+   fst; cphi
+   fld; ftmp2
+   fst; sphi
+   jmp i contrl
+
+t = t+1
+
+shipxy: 0
+   fld; absx
+   fad; x
+   fng
+   fst; shipx
+   fld; absy
+   fad; y
+   fng
+   fst; shipy
+   jmp i shipxy

scans/space-travel-2.s

@@ -0,0 +1,218 @@
+   " space travel 2
+
+abs: 0
+   dzm absx
+   dzm absx+1
+   dzm absx+2
+   dzm absy
+   dzm absy+1
+   dzm absy+2
+1:
+   dac absi
+   sna
+   jmp i absv
+   tad fppar
+   dac 9f+t
+   jmp invert
+   fld; ftmp1
+   fng
+   fad; absx
+   fst; absx
+   fld; ftmp2
+   fng
+   fad; absy
+   fst; absy
+   jmp invert
+   fld; ftmp1
+   fad; absx
+   fst; absx
+   fld; ftmp2
+   fad; absy
+   fst; absy
+   lac absi
+   tad ppar
+   dac 9f+t
+   lac i 9f+t
+   jmp 1b
+
+invert: 0
+   lac i 9f+t
+   dac fcplan
+   tad pww
+   dac 1f
+   dac 2f
+   lac fcplan
+   tad px
+   dac 3f
+   lac fcplan
+   tad py
+   dac 4f
+   fld; 1:,.
+   fng
+   fst; 2:,.
+   jms updpln
+   fld; 3:,.
+   fst; ftmp1
+   fld; 4:,.
+   fst; ftmp2
+   jmp i invert
+
+   t = t+1
+
+updpln: 0
+   lac fcplan
+   lmq
+   tad px
+   dac 1f
+   dac 5f
+   lacq
+   tad py
+   dac 3f
+   dac 6f
+   dac 0f
+   lacq
+   tad pw
+   dac 2f
+   dac 7f
+   lacq
+   tad pww
+   dac 4f
+   dac 8f
+
+   fld; 1:,.
+   fst; ftmp1
+   fmp; 2:,.
+   fst; ftmp2
+   fld; 3:,.
+   fmp; 4:,.
+   fng
+   fad; ftmp2
+   fst; 5:,.
+   fld; 6:,.
+   fmp; 7:,.
+   fst; ftmp2
+   fld; ftmp1
+   fmp; 8:,.
+   fad; ftmp2
+   fst; 0:,.
+   jmp updpln i
+
+updacc: 0
+   lac cplan
+   sad par
+   jmp upda2
+   jms absxy
+   fld; absx
+   fad; shipx
+   jmp 1f
+upda2:
+   fld; x
+   fng
+1:
+   fst; absx
+   fmp; absx
+   fst; ftmp1
+   lac cplan
+   sad par
+   jmp 1f
+   fld; absy
+   fad; shipy
+   jmp 2f
+1:
+   fld; y
+   fng
+2:
+   fst; absy
+   fmp; absy
+   fad; ftmp1
+   fst; dtmp1
+   sqrt
+   fst; dpar
+   lac cplan
+   sad par
+   skp
+   jmp upda5
+   fld; ox
+   fng
+   fad; x
+   fst; ftmp1
+   fmp; y
+   fst; horizv
+   fld; y
+   fng
+   fad; oy
+   fst; ftmp2
+   fmp; x
+   fad; horizv
+   fdv; dpar
+   fst; horizv
+   fld; dpar
+   fcp; rpar
+   sma
+   jmp upda5
+   lac lanflg
+   spa
+   jmp upda5
+   fld; ftmp1
+   fmp; ftmp1
+   fst; ftmp1
+   fld; ftmp2
+   fmp; ftmp2
+   fad; ftmp1
+   fcp; crash
+   spa
+   jmp 1f
+   lac dhalt
+   dac goflg
+   dac crflg
+1:
+   lac dhalt
+   dac lanflg
+   fld; rpar
+   fdv; dpar
+   fst; ftmp1
+   fmp; x
+   fst; x
+   fst; ox
+   fld;  ftmp1
+   fmp; y
+   fst; y
+   fst; oy
+   lac par
+   jms absxy
+   jms shipxy
+   jmp upda2
+upda5:
+   fcp; fardst
+   spa
+   jmp 1f
+   lac cplan
+   sna
+   jmp 1f
+   lac dhalt
+   dac grvflg
+   jmp i updacc
+1:
+   dzm grvflg
+   lac fcplan
+   tad accl
+   dac 1f
+   fld; 1:,.
+   fdv; dtmp1
+   fcp; maxa
+   spa
+   jmp 2f
+   fst; maxa
+   lac cplan
+   dac maxj
+2:
+   fdv; dpar
+   fst; ftmp1
+   fmp; absx
+   fad; ax
+   fst; ax
+   fld; ftmp1
+   fmp; absy
+   fad; ay
+   fst; ay
+   jmp i updacc

scans/space-travel-3.s

@@ -0,0 +1,185 @@
+   " space travel 3
+
+updshp: 0
+   lac forflg
+   spa
+   jmp .+4
+   lac bacflg
+   sma
+   jmp 3f
+   fld; ascale
+   lac  forflg
+   sma
+   jmp 1f
+   lac bacflg
+   sma
+   jmp 1f+1
+   fld; fpzero
+   jmp 2f
+1:
+   fng
+   lac scale
+   tad aexp
+   dac aexp
+   lac forflg
+   sma
+   jmp .+3
+2:
+   lac accflg
+   sma
+   jmp .+3
+   fad; maxa
+   fng
+   fst; ftmp1
+   fmp; ctheta
+   fad; ax
+   fst; ax
+   fld; ftmp1
+   fmp; stheta
+   fad; ay
+   fst; ay
+3:
+   fld; ox
+   fng
+   fad; ax
+   fst; ftmp1
+   fld; x
+   lac aexp
+   tad d1
+   dac aexp
+   fad; ftmp1
+   fst; ftmp2
+   fld; x
+   fst; ox
+   fld; ftmp1
+   fst; x
+   fld; oy
+   fng
+   fad; ay
+   fst; ftmp1
+   fld; y
+   lac aexp
+   tad d1
+   dac aexp
+   fad; ftmp1
+   fst; ftmp1
+   fld; y
+   fst; oy
+   fld; ftmp1
+   fst; y
+   lac par
+   sad maxj
+   jmp i updshp
+   jms absxy
+   jms shipxy
+   lac par
+   jms absv
+   fld; ox
+   fng
+   fad; x
+   fad; absx
+   fst; ox
+   fld; oy
+   fng
+   fad; y
+   fad; absy
+   fst; oy
+   lac maxj
+   dac par
+   jms absv
+   fld; ox
+   fng
+   fad; absx
+   fst; ox
+   fld; oy
+   fng
+   fad; absy
+   fst; oy
+   lac par
+   jms absxy
+   fld; absx
+   fad; shipx
+   fng
+   fst; x
+   fad; ox
+   fst; ox
+   fld; absy
+   fad; shipy
+   fng
+   fst; y
+fadins:
+   fad; oy
+   fst; oy
+   lac par
+   tad fppar
+   dac 1f
+   lac i 1f
+   tad prsq
+   dac 1f
+   fld; 1:,.
+   sqrt
+   fst; rpar
+   jms dspsca
+   lac par
+   jms dispname
+   jmp i updshp
+
+inscr: 0
+   fng
+   fix
+   tad d383
+   spa
+   jmp i inscr
+   tad dm768
+   sma
+   jmp i inscr
+   isz inscr
+   jmp i inscr
+
+absxy: 0
+   sna
+   jmp 7f
+   lmq
+   lac fldins
+   dac 2f-1
+   dac 4f-1
+   lacq
+1:
+   dac absi
+   sna
+   jmp i absxy
+   tad fppar
+   dac 9f+t
+   lac i 9f+t
+5:
+   tad px
+   dac 2f
+fldins:
+   fld; absx
+   fad; 2:,.
+   fst; absx
+   lac i 9f+t
+6:
+   tad py
+   dac 4f
+   fld; absy
+   fad; 4:,.
+   fst; absy
+   lac fadins
+   dac 2b-1
+   dac 4b-1
+   lac absi
+   tad ppar
+   dac 9f+t
+   lac i 9f+t
+   jmp 1b
+7:
+   dzm abs
+   dzm absx+1
+   dzm absx+2
+   dzm absy
+   dzm absy+1
+   dzm absy+2
+   jmp i absxy
+
+   t = t+1

scans/space-travel-4.s

@@ -0,0 +1,250 @@
+   " space travel 4
+
+displa: 0
+   lac locpar
+   sad cplan
+   skp
+   jmp 2f
+   lac locflg
+   sma
+   jmp 1f
+   fld; cphi
+   fmp; absy
+   fst; ftmp1
+   fld; sphi
+   fmp; absx
+   fad; ftmp1
+   fdv; dpar
+   fst; stheta
+   fld; sphi
+   fmp; absy
+   fng
+   fst; ftmp1
+   fld; cphi
+   fmp; absx
+   fad; ftmp1
+   fdv; dpar
+   fst; ctheta
+   jmp 2f
+1:
+   fld; sphi
+   fst; stheta
+   fld; cphi
+   fst; ctheta
+2:
+   fld; absx
+   sfmp; ctheta
+   fst; ftmp1
+   fld; absy
+   sfmp; stheta
+   fad; ftmp1
+   lac aexp
+   cma
+   tad scale
+   cma
+   dac aexp
+   fst; spy
+   dzm inflg
+   jms inscr
+      jmp 1f
+   tad o145777
+   dac clistp i
+   jms rotx
+   lac dhalt
+   dac inflg
+   jms inscr
+      jmp 1f
+   tad o161577
+   dac i clistp
+   lac cplan
+   jms dsplanet
+1:
+   jms drcirc
+   jmp i displa
+
+rotx: 0
+   fld; absx
+   sfmp; stheta
+   fst; ftmp1
+   fld; absy
+   sfmp; ctheta
+   fng
+   fad; ftmp1
+   lac aexp
+   cma
+   tad scale
+   cma
+   dac aexp
+   fst; spx
+   jmp i rotx
+
+surf: 0
+   -1
+   tad setx
+   cma
+   dac tsetx
+   lac setx
+   tad o141577
+   dac i clistp
+   -1
+   tad sety
+   cma
+   dac tsety
+   lac sety
+   tad o165777
+   dac clistp i
+   lac narcs
+   dac nt
+   fld; wx
+   fst; twx
+   fld; wy
+   fst; twy
+   fld; v
+   fng
+   fst; v
+2:
+   fld; v
+   sfmp twy
+   fng
+   fst; ftmp1
+   fld; vv
+   sfmp; twx
+   fad; ftmp1
+   fst; ftmp2
+   fld; v
+   sfmp; twx
+   fst; ftmp1
+   fld; vv
+   sfmp twy
+   fad; ftmp1
+   fst; twy
+   fad; spy
+   jms inscr
+      jmp 1f
+   tad tsety
+   dac dely
+   cma
+   tad d1
+   tad tsety
+   dac tsety
+   fld; ftmp2
+   fst; twx
+   fad; spx
+   jms inscr
+      jmp 1f
+   tad tsetx
+   dac dely
+   cma
+   tad d1
+   tad tsetx
+   dac tsetx
+   lac delx
+   sma
+   jmp .+3
+   cma
+   tad o41
+   alss 6
+   dac delx
+   dac dely
+   sma
+   jmp .+3
+   cma
+   tad o41
+   tad delx
+   tad o220000
+   dac i clistp
+   isz nt
+   jmp 2b
+   jmp i surf
+1:
+   isz surf
+   jmp i surf
+
+drcirc: 0
+   lac crvflg
+   spa
+   jmp i drcirc
+   lac fcplan
+   tad prsq
+   dac .+2
+   fld; ..
+   sqrt
+   lac aexp
+   cma
+   tad scale
+   cma
+   dac aexp
+   fst; dtmp1
+   fcp; thrs
+   spa
+   jmp i drcirc
+   fng
+   lac dpar
+   cma
+   tad scale
+   cma
+   dac dpar
+   fad; dpar
+   sfdv; dpar
+   fst; dtmp2
+   sfmp; spy
+   fst; wy
+   jms inscr
+      jmp i drcirc
+   dac sety
+   lac inflg
+   sma
+   jms rotx
+   fld; dtmp2
+   sfmp; spx
+   fst; wx
+   jms inscr
+      jmp i drcirc
+   dac setx
+   fld; spy
+   fng
+   fad; wx
+   fst; wy
+   fld; spx
+   fng
+   fad; wx
+   fst; wx
+   fld; dtmp1
+   sfmp; pid10
+   fcp; f400
+   spa
+   jmp 1f
+   lac d400
+   dac narcs
+   jmp 2f
+1:
+   fix
+   tad dm20
+   spa
+   cla
+   tad d20
+   dac narcs
+   flt
+2:
+   fst; dtmp1
+   -1
+   tad narcs
+   cma
+   dac narcs
+   fld; f2pi
+   sfdv; dtmp1
+   fst; v
+   sfmp; v
+   -1
+   tad aexp
+   dac aexp
+   fng
+   fad; fpone
+   fst; vv
+   lac o40004
+   dac i clistp
+   jms surf
+      jmp i drcirc
+   jms surf
+      jmp i drcirc
+   jmp i drcirc

scans/space-travel-5.s

@@ -0,0 +1,73 @@
+" space travel 5
+
+dsplanet: 0
+   tad points
+   dac 9f+t
+   lac i 9f+t
+   dac i clistp
+   lac o246256
+   dac i clistp
+   lac o253052
+   dac i clistp
+   lac o246036
+   dac i clistp
+   jmp dsplanet i
+
+dispname: 0
+   tad names
+   dac 9f+t
+   lac i 9f+t
+   tad dm1
+   dac 8
+   iaw namedsp-1
+   dac 9
+   -10
+   dac 9f+t
+1:
+   lac i 8
+   sna
+   jmp 2f
+   dac 9f+t+1
+   lrss 9
+   dac i 9
+   isz 9f+t
+   skp
+   jmp i dispname
+   lac 9f+t+1
+   and o177
+   sna
+   jmp 2f
+   dac i 9
+   isz 9f+t
+   jmp 1b
+   jmp i dispname
+2:
+   dzm i 9
+   isz 9f+t
+   jmp 2b
+   jmp i dispname
+
+t = t+2
+
+dspsca: 0
+   lac scale
+   sma
+   jmp 1f
+   lac 055 "-
+   dac dssca
+   -1
+   tad scale
+   cma
+   jmp 2f
+1:
+   lac o53 "+
+   dac dssca
+   lac scale
+2:
+   cll; idiv; 10
+   tad o60
+   dac dssca+2
+   lacq
+   tad o60
+   dac dssca+1
+   jmp i dpssca

scans/space-travel-6.s

@@ -0,0 +1,290 @@
+"space travel 6 -- tables
+
+names: .+1
+sun
+earth
+ariel
+callisto
+moon
+deimos
+dione
+enceladus
+europa
+ganymede
+hyperion
+iapetus
+io
+jupiter
+mars
+mercury
+mimas
+miranda
+neptune
+nereid
+oberon
+phobos
+phoebe
+pluto
+rhea
+saturn
+tethys
+titan
+triton
+umbriel
+uranus
+venus
+
+sun: <su>; <n
+earth: <ea>;<rt>;<h
+ariel: <ar>;<ie>; <l
+callisto: <ca>;<ll>;<is>;<to>;0
+moon: <mo>;<on>;0
+deimos: <de>;<im>;<os>;0
+dione: <di>;<on>;<e
+enceladus: <en>;<ce>;<la>;<du>;<s
+europa: <eu>;<ro>;<pa>;0
+ganymede: <ga>;<ny>;<me>;<de>;0
+hyperion: <hy>;<pe>;<ri>;<on>;0
+iapetus: <ia>;<pe>;<tu>;<s
+io: <io>;0
+jupiter: <ju>;<pi>;<te>;<r
+mars: <ma>;<rs>;0
+mercury: <me>;<cu>;<ry>;0
+mimas: <mi>;<ma>;<s
+miranda: <mi>;<ra>;<nd>;<a
+neptune: <ne>;<pt>;<un>;<e
+nereid: <ne>;<re>;<id>;0
+oberon: <ob>;<er>;<on>;0
+phobos: <ph>;<ob>;<os>;0
+phoebe: <ph>;<oe>;<be>;0
+pluto: <pl>;<ut>;<o
+rhea: <rh>;<ea>;0
+saturn: <sa>;<tu>;<rn>;0
+tethys: <te>;<th>;<ys>;0
+titan: <ti>;<ta>;<n
+triton: <tr>;<it>;<on>;0
+umbriel: <um>;<br>;<ie>;<l
+uranus: <ur>;<an>;<us>;0
+venus: <ve>;<nu>;<s
+
+points: .+1
+br3
+br2
+br0
+br2
+br1
+br0
+br1
+br0
+br1
+br2
+br0
+br1
+br1
+br3
+br2
+br1
+br0
+br0
+br3
+br0
+br1
+br0
+br0
+br1
+br1
+br3
+br1
+br2
+br1
+br0
+br3
+br2
+
+fppar:  .+1
+0;3;6;9;12;15;18;21
+24;27;30;33;36;39;42;45
+48;51;54;57;60;63;66;69
+72;75;78;81;84;87;90;93
+
+ppar: .+1
+0;0;036;015;01;016;031;031
+015;015;031;031;016;0;0;0
+031;036;0;022;036;016;031;0
+031;0;031;031;022;036;0;0
+
+prsq: .+1
+016;0272245;075341
+1;0200000;0
+-07;0244122;0506362
+-02;0251477;0620663
+-03;0230761;0127762
+-025;0320300;054474
+-06;0324134;0124211
+-010;0335416;0641570
+-04;0371372;0
+-06;0247430;0
+-011;0311150;0
+-05;0302622;0
+-02;0256475;0
+07;0376733;0
+-01;0221530;0
+-02;0235143;0
+-010;0217266;0
+-11;0274361;0
+04;0365471;0
+-012;0227176;0
+-06;0342454;0
+-023;0326340;0
+-013;0326265;0
+-02;0323774;0
+-05;0255140;0
+07;0263573;0
+-06;0223174;0
+-02;0251477;0
+-02;0235142;0
+-05;0223060;0
+05;0206115;0
+0;0362406;0
+
+accl: .+1
+0;0204365;0
+-023;0320324;0
+-036;0227207;0
+-017;0340500;0
+-030;0210041;0
+-063;0341666;0
+-034;0235122;0
+-037;0247531;0
+-031;0310316;0
+-027;0334427;0
+-041;0315203;0
+-033;0303403;0
+-030;0245752;0
+-017;0201414;0
+-026;0263753;0
+-026;0205241;0
+-040;0256464;0
+-041;0272051;0
+-017;0340566;0
+-043;0275073;0
+-034;0255345;0
+-060;0341650;0
+-044;0341552;0
+-020;0307762;0
+-033;0243712;0
+-014;0233053;0
+-035;0265543;0
+-027;0340500;0
+-027;0210344;0
+-037;0210777;0
+-017;0275653;0
+-023;0252667;0
+
+px: .+1
+0;000000;0
+015;0620356;0
+055;0360005;0
+010;0666214;0
+005;0704053;0
+002;0347600;0
+005;0310506;0
+006;0220622;0
+007;0310473;0
+004;0370065;0
+006;0304101;0
+011;0676631;0
+006;0653020;0
+020;0317202;0
+017;0644356;0
+013;0206414;0
+005;0245346;0
+004;0222264;0
+023;0261234;0
+001;0372225;0
+007;0646102;0
+001;0212446;0
+013;0773152;0
+024;0274557;0
+004;0227474;0
+020;0263122;0
+004;0333254;0
+010;0216672;0
+006;0231142;0
+006;0212701;0
+023;0650051;0
+016;0233751;0
+
+py: .+1
+000;0000000;0
+017;0664054;0
+002;0662035;0
+002;0662035;0
+010;0350757;0
+006;0334771;0
+000;0267000;0
+006;0726770;0
+004;0225752;0
+006;0201346;0
+010;0247536;0
+010;0343277;0
+011;0314411;0
+006;0712237;0
+021;0334656;0
+017;0342324;0
+016;0615151;0
+005;0644257;0
+005;0622456;0
+024;0224063;0
+012;0331314;0
+006;0640034;0
+001;0200024;0
+011;0243161;0
+023;0772355;0
+007;0644432;0
+022;0726324;0
+006;0260740;0
+010;0600213;0
+006;0237476;0
+005;0674734;0
+005;0674734;0
+023;0616334;0
+016;0327155;0
+
+pw: .+1
+.=.+32+32+32
+
+pww: .+1
+0000;0000000;0000000
+-054;0663265;0376074
+-036;0743326;0460356
+-043;0647730;0444215
+-045;0767246;0341205
+-034;0745027;0221674
+-036;0702670;0530661
+-034;0702340;0273047
+-037;0747771;0100452
+-041;0743411;0732756
+-044;0716603;0200021
+-050;0755641;0517072
+-035;0751602;0332677
+-072;0631066;0300145
+-056;0712656;0015171
+-050;0701167;0507203
+-033;0715124;0202507
+-035;0665024;0365605
+-073;0730064;0776551
+-054;0667362;0431776
+-043;0775760;0312631
+-030;0740613;0034530
+-055;0635657;0370276
+-074;0677234;0315321
+-037;0677234;0315321
+-037;0617102;0655555
+-066;0723370;0773672
+-035;0714526;0724272
+-043;0667633;0402706
+-040;0636053;0440472
+-037;0650025;0224325
+-071;0717663;0701773
+-052;0754612;0304722

scans/space-travel-7.s

@@ -0,0 +1,155 @@
+" space travel 7
+
+clistp = 017
+br0 = 040004
+br1 = 040005
+br2 = 040006
+br3 = 040007
+
+d10: 10
+d3: 3
+o246256: 0246256
+o253052: 0253052
+o246036: 0246036
+o177: 0177
+nplan: 32
+d1: 1
+d20: 20
+dm1: -1
+o141577: 0141577
+o161577: 0161577
+o164372: 0164372
+o114: 0114
+o20714: 020714
+d383: 383
+dm768: -768
+o145777: 0145777
+o165777: 0165777
+o7: 7
+o60: 060
+o55: 055
+o53: 053
+o41: 041
+o220000: 0220000
+d400: 400
+dm20: -20
+o40004: 040004
+
+fardst: 020;0200000; 0
+f2pi: 03;0311037;552421
+pid10: -01;0240662;756647
+thrs: 02;0200000;0
+f400: 011;0310000;0
+crash: -028;0200000;0
+stheta: 01;0200000;0
+ctheta: 0;0;0
+fpzero: 0;0;0
+scale: 0
+vscale: 6
+ascale: -1
+sdphi: -05;0253436;0700177
+cdphi: 000;0377743;0201725
+dhalt: 0400000
+fpone: 01;0200000;0
+
+9: .=.+t
+horizv: .=.+3
+.pbson: .=.+1
+.pbsint: .=.+1
+dspflg: .=.+1
+par: .=.+1
+absi: .=.+1
+absx: .=.+3
+absy: .=.+3
+v: .=.+3
+vv: .=.+3
+spx: .=.+3
+spy: .=.+3
+wx: .=.+3
+wy: .=.+3
+twx: .=.+3
+twy: .=.+3
+setx: .=.+1
+sety: .=.+1
+narcs: .=.+1
+nt: .=.+1
+inflg: .=.+1
+grvflg: .=.+1
+dtmp1: .=.+3
+dtmp2: .=.+3
+delx: .=.+1
+dely: .=.+1
+tsetx: .=.+1
+tsety: .=.+1
+accflg: .=.+1
+locpar: .=.+1
+erflg: .=.+1
+rpar: .=.+3
+dpar: .=.+3
+ax: .=.+3
+ay: .=.+3
+maxa: .=.+3
+maxj: .=.+1
+dcplan: .=.+1
+fcplan: .=.+1
+cplan: .=.+1
+shipx: .=.+3
+shipy: .=.+3
+x: .=.+3
+y: .=.+3
+ox: .=.+3
+oy: .=.+3
+lanflg: .=.+1
+goflg: .=.+1
+forflg: .=.+1
+bacflg: .=.+1
+sphi: .=.+3
+cphi: .=.+3
+ftmp1: .=.+3
+ftmp2: .=.+3
+locflg: .=.+3
+
+dsetx = 0140000
+dsety = 0164000
+vecx = 0120000
+vecy = 0124000
+m = 02000
+displist:
+   075057 "scale 1 intens 3 blink on lp 0 sym 0
+   dsetx 800
+   dsety 20
+dispcl:
+   0
+   060004 "intens 0 blink off
+   dsetx 0
+   dsety 20
+namedsp:
+   .=.+10
+   dsetx 400
+   dsety 20
+dssca:
+   .=. +3
+   040040 "scale 0
+   dsetx 127
+   dsety 250
+   vecx 768
+   dsetx 895
+   dsety 255
+   vecy 768
+   dsetx 895
+   dsety 1023
+   vecx m 768
+   dsetx 127
+   dsety 1023
+   vecy m 768
+   dsetx 127
+   dsety 255
+   vecx 768
+   dsetx 511
+   dsety 255
+   vecy 767
+   dsetx 127
+   dsety 639
+   vecx 767
+dspi:
+   0400000